forked from dmyerscough/tesla-powerwall-exporter
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
104 lines (90 loc) · 2.79 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
plugins {
id 'java'
id 'io.quarkus'
id 'jacoco'
id 'io.freefair.lombok' version '8.6'
id 'com.github.jmongard.git-semver-plugin' version '0.12.6'
id 'org.barfuin.gradle.jacocolog' version '3.1.0'
id "com.diffplug.spotless" version "6.25.0"
}
ext {
}
repositories {
mavenCentral()
mavenLocal()
}
semver {
// see https://github.com/jmongard/Git.SemVersioning.Gradle
patchPattern = "\\A(chore|fix|refactor|deps)(?:\\([^()]+\\))?:"
groupVersionIncrements = true
noDirtyCheck = true
gitDirectory = project.projectDir
createReleaseCommit = false
createReleaseTag = false
}
dependencies {
implementation enforcedPlatform("${quarkusPlatformGroupId}:${quarkusPlatformArtifactId}:${quarkusPlatformVersion}")
implementation 'io.quarkus:quarkus-scheduler'
implementation 'io.quarkus:quarkus-micrometer-registry-prometheus'
implementation 'io.quarkus:quarkus-arc'
implementation 'io.quarkus:quarkus-jackson'
implementation 'io.smallrye.reactive:smallrye-mutiny-vertx-web-client'
implementation 'org.slf4j:slf4j-api'
implementation 'org.apache.commons:commons-text'
implementation 'org.apache.commons:commons-lang3'
testImplementation 'io.quarkus:quarkus-junit5'
testImplementation 'org.wiremock:wiremock:3.6.0'
testImplementation 'io.quarkus:quarkus-jacoco'
}
group 'io.github.quotidianennui'
version semver.version
lombok {
disableConfig = true
}
java {
sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21
}
test {
systemProperty "java.util.logging.manager", "org.jboss.logmanager.LogManager"
// quarkus.jacoco.report=false in app.properties
// since we want jacocolog to emit its data
finalizedBy jacocoTestReport
jacoco {
// Force it into the same location as quarkus.
destinationFile = layout.buildDirectory.file('jacoco-quarkus.exec').get().asFile
excludeClassLoaders = ["*QuarkusClassLoader"]
}
}
jacocoTestReport {
reports {
xml.required = true
html.required = true
}
}
compileJava {
options.encoding = 'UTF-8'
options.compilerArgs << '-parameters'
}
compileTestJava {
options.encoding = 'UTF-8'
}
spotless {
java {
// Only spotlessCheck files that have changed in this branch, based on a diff
// from origin/main...
// Eventually becomes consistent.
ratchetFrom "origin/main"
// Allow // spotless:off // spotless:on
toggleOffOn()
// this conflicts with the standard behaviour of vscode-plugin + intellij
// so use gjf in default mode only which is a pure alphabetical import order.
// googleJavaFormat().reorderImports(false)
googleJavaFormat()
removeUnusedImports()
// Only useful if you turn off reorderImports() above.
// importOrder('\\#', 'java|javax|jakarta', '', 'lombok')
// fix formatting of type annotations
// formatAnnotations()
}
}