forked from facebook/react-native
-
Notifications
You must be signed in to change notification settings - Fork 126
/
RCTAppearance.mm
183 lines (152 loc) · 5.2 KB
/
RCTAppearance.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
/*
* Copyright (c) Facebook, Inc. and its affiliates.
*
* This source code is licensed under the MIT license found in the
* LICENSE file in the root directory of this source tree.
*/
#import "RCTAppearance.h"
#import <FBReactNativeSpec/FBReactNativeSpec.h>
#import <React/RCTConstants.h>
#import <React/RCTEventEmitter.h>
#import "CoreModulesPlugins.h"
using namespace facebook::react;
NSString *const RCTAppearanceColorSchemeLight = @"light";
NSString *const RCTAppearanceColorSchemeDark = @"dark";
static BOOL sAppearancePreferenceEnabled = YES;
void RCTEnableAppearancePreference(BOOL enabled)
{
sAppearancePreferenceEnabled = enabled;
}
static NSString *sColorSchemeOverride = nil;
void RCTOverrideAppearancePreference(NSString *const colorSchemeOverride)
{
sColorSchemeOverride = colorSchemeOverride;
}
#if !TARGET_OS_OSX // TODO(macOS GH#774)
NSString *RCTColorSchemePreference(UITraitCollection *traitCollection)
{
#if defined(__IPHONE_OS_VERSION_MAX_ALLOWED) && defined(__IPHONE_13_0) && \
__IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_13_0
if (@available(iOS 13.0, *)) {
static NSDictionary *appearances;
static dispatch_once_t onceToken;
if (sColorSchemeOverride) {
return sColorSchemeOverride;
}
dispatch_once(&onceToken, ^{
appearances = @{
@(UIUserInterfaceStyleLight) : RCTAppearanceColorSchemeLight,
@(UIUserInterfaceStyleDark) : RCTAppearanceColorSchemeDark
};
});
if (!sAppearancePreferenceEnabled) {
// Return the default if the app doesn't allow different color schemes.
return RCTAppearanceColorSchemeLight;
}
traitCollection = traitCollection ?: [UITraitCollection currentTraitCollection];
return appearances[@(traitCollection.userInterfaceStyle)] ?: RCTAppearanceColorSchemeLight;
}
#endif
// Default to light on older OS version - same behavior as Android.
return RCTAppearanceColorSchemeLight;
}
#else // [TODO(macOS GH#774)
NSString *RCTColorSchemePreference(NSAppearance *appearance)
{
static NSDictionary *appearances;
static dispatch_once_t onceToken;
dispatch_once(&onceToken, ^{
appearances = @{
NSAppearanceNameAqua: RCTAppearanceColorSchemeLight,
NSAppearanceNameDarkAqua: RCTAppearanceColorSchemeDark
};
});
if (!sAppearancePreferenceEnabled) {
// Return the default if the app doesn't allow different color schemes.
return RCTAppearanceColorSchemeLight;
}
appearance = appearance ?: [NSAppearance currentAppearance];
NSAppearanceName appearanceName = [appearance bestMatchFromAppearancesWithNames:@[NSAppearanceNameAqua, NSAppearanceNameDarkAqua]];
return appearances[appearanceName] ?: RCTAppearanceColorSchemeLight;
}
#endif // ]TODO(macOS GH#774)
@interface RCTAppearance () <NativeAppearanceSpec>
@end
@implementation RCTAppearance {
NSString *_currentColorScheme;
}
RCT_EXPORT_MODULE(Appearance)
+ (BOOL)requiresMainQueueSetup
{
return YES;
}
- (dispatch_queue_t)methodQueue
{
return dispatch_get_main_queue();
}
- (std::shared_ptr<TurboModule>)getTurboModule:(const ObjCTurboModule::InitParams &)params
{
return std::make_shared<NativeAppearanceSpecJSI>(params);
}
#if TARGET_OS_OSX // [TODO(macOS GH#774): on macOS don't lazy init _currentColorScheme because [NSAppearance currentAppearance] cannot be executed on background thread.
- (instancetype)init
{
if (self = [super init]) {
_currentColorScheme = RCTColorSchemePreference(nil);
}
return self;
}
#endif // ]TODO(macOS GH#774)
RCT_EXPORT_SYNCHRONOUS_TYPED_METHOD(NSString *, getColorScheme)
{
#if !TARGET_OS_OSX // [TODO(macOS GH#774)
_currentColorScheme = RCTColorSchemePreference(nil);
#endif // ]TODO(macOS GH#774)
return _currentColorScheme;
}
- (void)appearanceChanged:(NSNotification *)notification
{
NSDictionary *userInfo = [notification userInfo];
#if !TARGET_OS_OSX // TODO(macOS GH#774)
UITraitCollection *traitCollection = nil;
if (userInfo) {
traitCollection = userInfo[RCTUserInterfaceStyleDidChangeNotificationTraitCollectionKey];
}
NSString *newColorScheme = RCTColorSchemePreference(traitCollection);
#else // [TODO(macOS GH#774)
NSAppearance *appearance = nil;
if (userInfo) {
appearance = userInfo[RCTUserInterfaceStyleDidChangeNotificationTraitCollectionKey];
}
NSString *newColorScheme = RCTColorSchemePreference(appearance);
#endif // ]TODO(macOS GH#774)
if (![_currentColorScheme isEqualToString:newColorScheme]) {
_currentColorScheme = newColorScheme;
[self sendEventWithName:@"appearanceChanged" body:@{@"colorScheme" : newColorScheme}];
}
}
#pragma mark - RCTEventEmitter
- (NSArray<NSString *> *)supportedEvents
{
return @[ @"appearanceChanged" ];
}
- (void)startObserving
{
if (@available(iOS 13.0, *)) {
[[NSNotificationCenter defaultCenter] addObserver:self
selector:@selector(appearanceChanged:)
name:RCTUserInterfaceStyleDidChangeNotification
object:nil];
}
}
- (void)stopObserving
{
if (@available(iOS 13.0, *)) {
[[NSNotificationCenter defaultCenter] removeObserver:self];
}
}
@end
Class RCTAppearanceCls(void)
{
return RCTAppearance.class;
}