-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
1471 lines (1244 loc) · 50.8 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* Copyright 2019 ThoughtWorks, Inc.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
import com.github.jk1.license.ReportTask
import com.github.jk1.license.filter.LicenseBundleNormalizer
import com.github.jk1.license.render.JsonReportRenderer
import groovy.io.FileType
import nl.javadude.gradle.plugins.license.License
import org.apache.tools.ant.filters.FixCrLfFilter
import java.security.SecureRandom
import java.util.stream.Collectors
buildscript {
repositories {
maven {
url "https://plugins.gradle.org/m2/"
}
}
dependencies {
classpath 'org.owasp:dependency-check-gradle:5.3.0'
classpath 'com.github.ben-manes:gradle-versions-plugin:0.25.0'
classpath 'gradle.plugin.com.hierynomus.gradle.plugins:license-gradle-plugin:0.15.0'
classpath 'com.github.jk1:gradle-license-report:1.7'
classpath "com.github.jruby-gradle:jruby-gradle-core-plugin:2.0.0-alpha.7"
}
}
apply plugin: 'base'
apply plugin: 'com.github.jk1.dependency-license-report'
apply plugin: 'org.owasp.dependencycheck'
if (file('build-ext.gradle').exists()) {
apply from: 'build-ext.gradle'
}
def script = this
def gitRevision = { ->
def hashStdOut = new ByteArrayOutputStream()
exec {
commandLine "git", "log", "-n", "1", "--format=%H"
standardOutput = hashStdOut
workingDir = script.buildscript.sourceFile.canonicalFile.parent
}
return hashStdOut.toString().trim()
}
def releaseRevision = { ->
def hashStdOut = new ByteArrayOutputStream()
exec {
commandLine "git", "log", "--pretty=format:"
standardOutput = hashStdOut
workingDir = script.buildscript.sourceFile.canonicalFile.parent
}
return hashStdOut.size().toString()
}
def getVersion = { ... args ->
ByteArrayOutputStream stdout = new ByteArrayOutputStream()
try {
project.exec {
commandLine = args
standardOutput = stdout
errorOutput = stdout
ignoreExitValue = true
}
} catch (Exception ignored) {
return "could not determine version!"
}
return stdout.toString().trim()
}
List<String> partitionFiles(Collection originalFiles) {
def files = originalFiles.unique().sort()
def seed = System.getenv('GO_PIPELINE_COUNTER')?.toInteger() ?: System.getenv('PARTITION_SEED')?.toInteger() ?: new SecureRandom().nextInt().abs()
def totalWorkers = System.getenv('GO_JOB_RUN_COUNT')?.toInteger() ?: 1
def currentWorkerIndex = System.getenv('GO_JOB_RUN_INDEX')?.toInteger() ?: 1
Integer testsPerBucket = Math.ceil((double) files.size() / totalWorkers)
rootProject.logger.quiet("Partitioning ${files.size()} files into ${totalWorkers} buckets with approx ${testsPerBucket} files per bucket. Using seed ${seed}.")
rootProject.logger.quiet("To reproduce the test failure, run with:")
rootProject.logger.quiet("PARTITION_SEED=${seed} GO_JOB_RUN_COUNT=${totalWorkers} GO_JOB_RUN_INDEX=${currentWorkerIndex} ./gradlew YOUR_TARGET")
// random shuffle, every agent uses the same seed, so shuffling is predictable
Collections.shuffle(files, new Random(seed))
def allPartitions = files.collate(testsPerBucket)
def currentPartition = allPartitions[currentWorkerIndex - 1]
return currentPartition ?: []
}
def GO_VERSION_PREVIOUS = '20.1.0'
def GO_VERSION_SEGMENTS = [year: 20, releaseInYear: 2, patch: 0]
def GO_VERSION_NEXT = '20.3.0'
def GO_VERSION = [GO_VERSION_SEGMENTS.year, GO_VERSION_SEGMENTS.releaseInYear, GO_VERSION_SEGMENTS.patch].join('.')
def DIST_VERSION = releaseRevision()
def GIT_REVISION = gitRevision()
if (System.getenv().containsKey("GO_SERVER_URL")) {
def separator = "=".multiply(72)
println separator
println "Gradle version: ${gradle.gradleVersion}"
println "JVM: ${System.getProperty('java.version')} (${System.getProperty('java.vm.vendor')} ${System.getProperty('java.vm.version')})"
println "OS: ${System.getProperty('os.name')} ${System.getProperty('os.version')} ${System.getProperty('os.arch')}"
println separator
println("")
def isWindows = org.gradle.internal.os.OperatingSystem.current().isWindows()
println("Tool Versions")
println(separator)
println("node: ${getVersion("node", "--version")}")
println(" npm: ${getVersion((isWindows ? "npm.cmd" : 'npm'), "--version")}")
println("yarn: ${getVersion((isWindows ? "yarn.cmd" : 'yarn'), "--version")}")
println(" git: ${getVersion("git", "--version")}")
println(" hg: ${getVersion("hg", "--quiet", "--version")}")
println(" svn: ${getVersion("svn", "--quiet", "--version")}")
println(" p4: ${getVersion("p4", "-V").readLines().grep(~/Rev.*/).join("")}")
println(" p4d: ${getVersion("p4d", "-V").readLines().grep(~/Rev.*/).join("")}")
println(" gcc: ${getVersion("gcc", "-dumpversion")}")
println(" g++: ${getVersion("g++", "-dumpversion")}")
println(separator)
println("")
}
rootProject.ext.previousVersion = GO_VERSION_PREVIOUS
rootProject.ext.nextVersion = GO_VERSION_NEXT
rootProject.ext.goVersionSegments = GO_VERSION_SEGMENTS
rootProject.ext.goVersion = GO_VERSION
rootProject.ext.distVersion = DIST_VERSION
rootProject.ext.fullVersion = DIST_VERSION ? "${GO_VERSION}-${DIST_VERSION}" : GO_VERSION
rootProject.ext.gitRevision = GIT_REVISION
rootProject.ext.copyrightYear = Calendar.getInstance().get(Calendar.YEAR)
rootProject.ext.commandRepoUrl = System.getenv('COMMAND_REPO_URL') ? System.getenv('COMMAND_REPO_URL') : "git://github.com/gocd/go-command-repo"
project.ext.defaultJvmArgs = []
project.ext.compilerOptions = [
sourceCompatibility: 11,
targetCompatibility: 11,
]
rootProject.ext.versions = [
activeMQ : '5.15.10',
apacheAnt : '1.10.7',
apacheHttpComponents : '4.5.6',
aspectj : '1.9.5',
assertJ : '3.12.2',
bouncyCastle : '1.59', // bouncycastle version has to be compatible with the jruby version
bundler : '2.1.1',
cglib : '3.3.0',
cloning : '1.9.11',
commonsBeanutils : '1.9.3',
commonsCodec : '1.13',
commonsCollections : '3.2.2',
commonsCollections4 : '4.4',
commonsConfiguration : '2.6',
commonsDbcp : '2.7.0',
commonsDigester : '2.1',
commonsDigester3 : '3.2',
commonsFileUpload : '1.4',
commonsIO : '2.6',
commonsLang : '2.6',
commonsLang3 : '3.9',
commonsPool : '2.8.0',
dbunit : '2.7.0',
ehcache : '2.10.6',
felix : '5.6.10',
freemarker : '2.3.29',
gson : '2.8.6',
guava : '28.2-jre',
h2db : '1.3.168',
hamcrest : '2.2',
hibernate : '3.6.10.Final',
jackson : '2.9.9',
javaAssist : '3.12.1.GA',
javaxAnnotation : '1.3.2',
jaxen : '1.2.0',
jcommander : '1.78',
jdom : '2.0.6',
jetty : '9.4.19.v20190610',
jgit : '5.1.3.201810200350-r',
jodaTime : '2.9.9', // joda-time version has to be compatible with the jruby version
jolt : '0.1.1',
jruby : '9.2.0.0',
jsonUnit : '2.14.0',
jsoup : '1.13.1',
junit : '4.13',
junit5 : '5.6.0',
logback : '1.2.3',
lombok : '1.18.12',
mail : '1.6.1',
mockito : '3.3.0',
mybatis : '3.4.6',
mybatisSpring : '1.3.2',
nanohttpd : '2.3.1',
objenesis : '2.6',
oro : '2.0.8',
quartz : '2.3.1',
rack : '1.1.21',
semanticVersion : '2.1.0',
servletApi : '3.1.0',
slf4j : '1.7.30',
snakeYaml : '1.19',
spark : '2.7.2',
spring : '4.3.25.RELEASE',
spring4jUnit5Extension: '1.5.0',
springSecurity : '4.2.13.RELEASE',
systemRules : '1.19.0',
tanuki : '3.5.41',
tini : '0.18.0',
tinybundles : '3.0.0',
tokenBucket : '1.7',
urlrewrite : '3.2.0',
velocityToolsView : '1.4',
xmlUnit : '2.6.3',
seleniumDrivers : [
chromedriver : '2.41',
geckodriver : '0.21.0',
iedriverserver: '3.14.0'
],
adoptOpenjdk : [
featureVersion: 13,
interimVersion: 0, // set to `null` for the first release
updateVersion : 1, // set to `null` for the first release
buildVersion : 9
]
]
dependencyCheck {
cve {
def baseUrl
if (System.getenv().containsKey("GO_SERVER_URL")) {
baseUrl = "https://nexus.gocd.io/repository/nvd-nist"
} else {
baseUrl = "https://nvd.nist.gov/feeds"
}
urlModified = "${baseUrl}/json/cve/1.0/nvdcve-1.0-modified.json.gz"
urlBase = "${baseUrl}/json/cve/1.0/nvdcve-1.0-%d.json.gz"
}
suppressionFile = rootProject.file('buildSrc/dependency-check-suppress.xml').toPath().toString()
}
allprojects {
apply plugin: 'idea'
apply plugin: 'jacoco'
group = 'com.thoughtworks.go'
version = project.fullVersion
buildDir = "${projectDir}/target"
repositories {
mavenCentral()
maven { url "https://dl.bintray.com/gocd-maven-repo/generic/gocd" }
}
jacoco {
toolVersion = "0.8.2"
}
}
idea {
project {
jdkName = '11'
languageLevel = '11'
}
}
subprojects {
if (!project.childProjects.isEmpty()) {
return
}
apply plugin: 'base'
apply plugin: 'com.github.ben-manes.versions'
if (project.path != ':test:http-mocks') {
apply plugin: "com.github.hierynomus.license"
license {
skipExistingHeaders = false
strictCheck = true
ext.year = project.copyrightYear
exclude '**/*.erb'
exclude '**/*.ejs'
exclude '**/*.keep'
exclude '**/*.md'
exclude '**/*.jar'
exclude '**/*.json'
exclude '**/*.html'
exclude '**/*.zip'
exclude '**/*.png'
exclude '**/*.jpg'
exclude '**/*.jpeg'
exclude '**/*.gif'
exclude '**/*.woff'
exclude '**/*.woff2'
exclude '**/*.ttf'
exclude '**/*.eot'
exclude '**/*.svg'
exclude '**/*.json'
exclude '**/*.scss.d.ts'
exclude '**/.*.json'
exclude '**/hg.template'
exclude '**/available.toggles'
exclude '**/META-INF/services/*'
exclude '**/node_modules/**'
exclude '**/javascripts/lib/**'
exclude '**/gems/jruby/**'
exclude '**/tmp/**'
exclude '**/logs/**'
exclude '**/log/**'
exclude '**/RubyRipper.java'
exclude '**/reset-fonts-grids.scss'
exclude '**/mock-ajax.js'
exclude '**/mithril.js'
exclude '**/crel.js'
exclude '**/JavaVersion.java'
exclude '**/ansi_up.js'
exclude '**/robots.txt'
exclude '**/rails/bin/**'
// used by intellij for type hints when editing ftl files, intellij gets confused if it sees a license header in this file
exclude '**/freemarker_implicit.ftl'
header rootProject.file('buildSrc/Apache-2.0.txt')
headerDefinitions {
intellijStyleXML {
firstLine = "<!--"
beforeEachLine = ' ~ '
endLine = " -->"
afterEachLine = ''
skipLinePattern = "^<\\?xml.*>\$"
firstLineDetectionPattern = "(\\s|\\t)*<!--.*\$"
lastLineDetectionPattern = ".*-->(\\s|\\t)*\$"
allowBlankLines = true
isMultiline = true
padLines = false
}
intellijStyleFTL {
firstLine = "<#--"
beforeEachLine = ' '
endLine = " -->"
afterEachLine = ''
firstLineDetectionPattern = "(\\s|\\t)*<#--.*\$"
lastLineDetectionPattern = ".*-->(\\s|\\t)*\$"
allowBlankLines = true
isMultiline = true
padLines = false
}
}
mapping {
java = 'SLASHSTAR_STYLE'
groovy = 'SLASHSTAR_STYLE'
scss = 'SLASHSTAR_STYLE'
sass = 'SLASHSTAR_STYLE'
css = 'SLASHSTAR_STYLE'
xml = 'intellijStyleXML'
xsl = 'intellijStyleXML'
xsd = 'intellijStyleXML'
ftl = 'intellijStyleFTL'
ftlh = 'intellijStyleFTL'
ts = 'SLASHSTAR_STYLE'
tsx = 'SLASHSTAR_STYLE'
msx = 'SLASHSTAR_STYLE'
js = 'SLASHSTAR_STYLE'
}
}
}
if (!project.fileTree("src/main/java").files.isEmpty()) {
apply plugin: 'java'
apply plugin: 'pmd'
apply plugin: 'com.github.jk1.dependency-license-report'
dependencyUpdates.resolutionStrategy {
componentSelection { rules ->
rules.all { ComponentSelection selection ->
boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'preview', 'b', 'ea'].any { qualifier ->
selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-+]*/
}
if (rejected) {
selection.reject('Release candidate')
}
}
}
}
sourceCompatibility = project.compilerOptions.sourceCompatibility
targetCompatibility = project.compilerOptions.targetCompatibility
buildDir = "${projectDir}/target"
configurations {
packagingOnly { transitive = false }
extractedAtTopLevel { transitive = false }
fatJarConfig
testOutput {
extendsFrom testRuntime
transitive = true
}
}
sourceSets {
main {
java {
compileClasspath += configurations.compileOnly
}
}
test {
java {
compileClasspath += configurations.compileOnly
runtimeClasspath += configurations.compileOnly
}
}
}
licenseReport {
renderers = [new JsonReportRenderer("index.json", false)]
excludeGroups = ["com.thoughtworks.go"]
filters = [new LicenseBundleNormalizer()]
outputDir = file("${project.buildDir}/reports/dependency-license")
configurations = ['compile', 'compileOnly', 'packagingInLibDir']
}
tasks.withType(ReportTask) { ReportTask reportTask ->
reportTask.outputs.cacheIf { true }
project.configurations.each { config ->
if (config.name in project.licenseReport.configurations) {
reportTask.inputs.files(config)
}
}
}
task testJar(type: Jar, description: "Assembles a jar archive containing the test classes.") {
archiveClassifier = 'tests'
from sourceSets.test.output
}
pmd {
ignoreFailures = true
toolVersion = '6.17.0'
ruleSetFiles = files(rootProject.file('buildSrc/pmd.xml'))
ruleSets = []
incrementalAnalysis = true
}
}
task cleanLogs(type: Delete) {
delete 'logs'
}
task cleanApiOut(type: Delete) {
delete 'out'
}
clean.dependsOn cleanLogs, cleanApiOut
check.dependsOn 'license'
tasks.withType(Jar) { jarTask ->
manifest {
attributes(
'Go-Version': project.version,
'ImplementationVersion': project.version,
'Go-Revision': project.gitRevision,
'Implementation-Title': project.name,
'Implementation-Version': project.version,
'Source-Compatibility': project.compilerOptions.sourceCompatibility,
'Target-Compatibility': project.compilerOptions.targetCompatibility
)
}
includeEmptyDirs false
duplicatesStrategy DuplicatesStrategy.EXCLUDE
if (jarTask.name == 'testJar') {
project.artifacts.add 'testOutput', jarTask
} else {
project.artifacts.add 'archives', jarTask
}
}
tasks.withType(AbstractArchiveTask) {
includeEmptyDirs false
duplicatesStrategy DuplicatesStrategy.EXCLUDE
preserveFileTimestamps = false
reproducibleFileOrder = true
}
tasks.withType(Exec) {
if (logger.isInfoEnabled()) {
standardOutput = System.out
errorOutput = System.err
} else {
standardOutput = new ByteArrayOutputStream()
errorOutput = new ByteArrayOutputStream()
}
}
tasks.withType(GroovyCompile).configureEach {
options.incremental = true
}
tasks.withType(JavaCompile) { compileTask ->
options.warnings = false
options.encoding = "UTF-8"
options.compilerArgs += '-Xlint:-deprecation'
}
project.afterEvaluate {
tasks.withType(License) { License thisTask ->
def sourceSetName = thisTask.name.replaceFirst('licenseFormat', '').replaceFirst('license', '')
def mappedSourceSet = sourceSets.find { sourceSet -> sourceSet.name.toLowerCase().equals(sourceSetName.toLowerCase()) }
if (project.path == ':server' && sourceSetName.toLowerCase() == 'test') {
thisTask.source += project.file("rails/")
return
}
if (thisTask.name.toLowerCase().contains('test')) {
thisTask.source -= mappedSourceSet.resources
}
if (project.path == ':test:test-utils') {
thisTask.source -= mappedSourceSet.resources
}
}
}
tasks.withType(Test) { Test testTask ->
dependsOn 'jar'
// run tests even when inputs have not changed
// outputs.upToDateWhen { false }
testTask.useJUnitPlatform()
def allTestClasses
maxParallelForks = project.hasProperty('maxParallelForks') ? project.maxParallelForks as int : 1
// fixup a tempdir that is predictable and we can clean it up later
def tmpDir = project.file("${System.getProperty('java.io.tmpdir')}/gocd-tests/${new BigInteger(32, new SecureRandom()).toString(32)}")
systemProperty 'java.io.tmpdir', tmpDir
jvmArgs += project.defaultJvmArgs
doFirst {
// workaround for https://github.com/unbroken-dome/gradle-testsets-plugin/issues/40
classpath += rootProject.findProject(':test:test-utils').files("resource-include-in-all-projects")
}
defaultCharacterEncoding = "UTF-8"
filter {
failOnNoMatchingTests = true
}
doFirst {
project.logger.info("Setting tmpdir ${tmpDir}")
project.delete(tmpDir)
tmpDir.mkdirs()
List<String> files = []
testTask.testClassesDirs.files.each { File classDir ->
if (classDir.exists()) {
classDir.eachFileRecurse(FileType.FILES) { f ->
def relPath = new File(classDir.toURI().relativize(f.toURI()).toString()).toString().replaceAll(/\$.*/, '.*').replaceAll(/\.class/, '.*')
files << relPath
}
}
}
files = files.unique()
List testsToRun = partitionFiles(files)
allTestClasses = getTestClassesForTask(testsToRun)
List testsToIgnore = files - testsToRun
testsToIgnore.each { f ->
testTask.exclude f
}
testsToRun.each { f ->
testTask.include f
}
}
beforeTest { TestDescriptor test ->
allTestClasses.remove(test.className)
}
beforeSuite { TestDescriptor test ->
allTestClasses.remove(test.className)
}
doLast {
project.logger.info("Deleting tmpdir ${tmpDir}")
project.delete(tmpDir)
def allowTestsToBeSkipped = false
if (project.hasProperty("allowTestsToBeSkipped")) {
allowTestsToBeSkipped = Boolean.parseBoolean(project.property("allowTestsToBeSkipped"))
}
if (!allTestClasses.empty && !allowTestsToBeSkipped) {
throw new GradleException("Missed the following classes to test: ${allTestClasses}".toString())
}
}
testLogging {
showStandardStreams = project.path != ':server'
exceptionFormat 'full'
beforeSuite { suite ->
if (suite.parent) {
logger.quiet("Running ${suite.name}")
}
}
afterSuite { suite, result ->
if (suite.parent) {
logger.quiet("Tests run: ${result.testCount}, Failures: ${result.failedTestCount}, Skipped: ${result.skippedTestCount}, Time elapsed: ${(result.endTime - result.startTime) / 1000.00} sec")
if (result.resultType == TestResult.ResultType.FAILURE) {
logger.quiet("Test ${suite.name} FAILED")
}
} else {
logger.quiet("Total tests run: ${result.testCount}, Failures: ${result.failedTestCount}, Skipped: ${result.skippedTestCount}, Time elapsed: ${(result.endTime - result.startTime) / 1000.00} sec")
}
}
}
}
tasks.withType(Delete) { Delete deleteTask ->
project.afterEvaluate {
idea {
module {
excludeDirs += deleteTask.targetFiles
}
}
}
}
configurations.all { configuration ->
def versionOverrides = [
"com.fasterxml.jackson.core:jackson-annotations": project.versions.jackson,
"com.fasterxml.jackson.core:jackson-core" : project.versions.jackson,
"com.fasterxml.jackson.core:jackson-databind" : project.versions.jackson,
"commons-beanutils:commons-beanutils" : project.versions.commonsBeanutils
]
configuration.resolutionStrategy.eachDependency { DependencyResolveDetails details ->
def overrideVersion = versionOverrides[details.requested.group + ":" + details.requested.name]
if (overrideVersion != null && details.requested.version != overrideVersion) {
logger.info "Overriding dependency ${details.requested.group}:${details.requested.name} version ${details.requested.version} --> $overrideVersion"
details.useVersion overrideVersion
}
// replace log4j and commons-logging implementations with the slf4j apis that redirect logs to slf4j
// see https://www.slf4j.org/legacy.html
if (details.requested.name == 'log4j' && details.requested.group == 'log4j') {
details.useTarget group: 'org.slf4j', name: 'log4j-over-slf4j', version: project.versions.slf4j
}
if (details.requested.name == 'commons-logging' && details.requested.group == 'commons-logging') {
details.useTarget group: 'org.slf4j', name: 'jcl-over-slf4j', version: project.versions.slf4j
}
}
}
if (project.path.startsWith(':api:') || project.path.startsWith(':spark:')) {
project.afterEvaluate {
project.configurations*.exclude(group: 'org.junit.vintage')
project.configurations*.exclude(group: 'junit')
}
}
project.configurations*.exclude(group: 'xalan')
project.configurations*.exclude(group: 'xml-apis')
}
task allDependencies {
dependsOn allprojects.collect { "$it.path:dependencies" }
description = "Print dependency tree of all projects"
}
task compileAll { compileAllTask ->
group LifecycleBasePlugin.BUILD_GROUP
allprojects.collect { Project prj ->
compileAll.dependsOn(prj.getTasks().withType(JavaCompile))
compileAll.dependsOn(prj.getTasks().withType(GroovyCompile))
}
}
task prepare(dependsOn: compileAll)
task sparkTest { thisTask ->
group LifecycleBasePlugin.VERIFICATION_GROUP
description = "Run all api tests"
(project(':api').subprojects + project(':spark').subprojects).each { Project subPrj ->
thisTask.dependsOn subPrj.tasks.withType(Test)
thisTask.dependsOn subPrj.tasks.withType(JacocoReport)
}
finalizedBy 'sparkTestJunitHtmlReport'
}
task sparkTestJunitHtmlReport(type: TestReport) {
dependsOn sparkTest
reportOn project(':api').subprojects*.test
reportOn project(':spark').subprojects*.test
destinationDir = file("${project.buildDir}/reports/tests/sparkTest")
}
task sparkTestJacocoMerge(type: JacocoMerge) { thisTask ->
dependsOn sparkTest
group LifecycleBasePlugin.VERIFICATION_GROUP
description = "Combine coverage reports for api modules"
// add a no-op execution data file
executionData file("${project.buildDir}/no-op.exec")
doFirst {
(project(':api').subprojects + project(':spark').subprojects).each { subproject ->
TaskCollection<JacocoReport> jacocoReportTasks = subproject.tasks.withType(JacocoReport)
jacocoReportTasks.all { eachReportTask ->
thisTask.executionData(eachReportTask.executionData)
}
}
executionData = files(executionData.findAll { it.exists() })
}
}
task sparkTestJacocoReport(type: JacocoReport, group: 'Coverage reports') { JacocoReport thisTask ->
description = 'Generates an aggregate report from api subprojects'
dependsOn sparkTestJacocoMerge
executionData sparkTestJacocoMerge.destinationFile
sourceDirectories.setFrom(files([]))
classDirectories.setFrom(files([]))
(project(':api').subprojects + project(':spark').subprojects).each { subproject ->
TaskCollection<JacocoReport> jacocoReportTasks = subproject.tasks.withType(JacocoReport)
jacocoReportTasks.all { eachReportTask ->
thisTask.sourceDirectories.from(files(subproject.sourceSets.main.allSource.srcDirs))
thisTask.classDirectories.from(files(subproject.sourceSets.main.output))
}
}
reports {
html.enabled = true
xml.enabled = true
}
}
private void forAllTask(Closure<Task> closure) {
allprojects.each { Project subPrj ->
// afterEvaluate, because the testsset plugin defines tasks much later
subPrj.afterEvaluate {
subPrj.tasks.withType(Test).each { eachTestTask ->
if (!(eachTestTask.path in [':server:integrationTest'])) {
closure.call(eachTestTask)
}
}
}
}
}
task allTests { thisTask ->
group LifecycleBasePlugin.VERIFICATION_GROUP
description = "Run all tests"
dependsOn ':server:lint'
forAllTask { Test eachTestTask ->
thisTask.dependsOn eachTestTask
}
finalizedBy 'allTestsJunitHtmlReport'
}
task allTestsJunitHtmlReport(type: TestReport) { TestReport thisTask ->
group LifecycleBasePlugin.VERIFICATION_GROUP
description = "Run all api tests"
forAllTask { Test eachTestTask ->
thisTask.reportOn eachTestTask.binResultsDir
eachTestTask.finalizedBy(thisTask)
}
destinationDir = file("${project.buildDir}/reports/tests/allTests")
}
static def toCamelCase(String input) {
return input.split("[^a-zA-Z0-9]").collect { it.capitalize() }.join("")
}
static List<String> getTestClassesForTask(List<String> testsToRun) {
return testsToRun.stream()
.filter { testToRun -> !testToRun.matches(".*[/|\\\\].*Abstract.*Test.*") }
.filter { testToRun -> testToRun.endsWith("Test.*") }
.map { testToRun -> testToRun.replaceAll(".\\*", "").replaceAll("[^\\w.*]", ".") }
.collect(Collectors.toList())
}
task newSPA {
description = "Helper to create a new SPA. Pass `-PspaName=maintenance_mode"
doFirst {
String spaName = project.spaName
String entityName = toCamelCase(spaName)
String modelsBase = "${project(':server').webAppDir}/WEB-INF/rails/webpack/models/${spaName}"
String pagesBase = "${project(':server').webAppDir}/WEB-INF/rails/webpack/views/pages"
String widgetBase = "${pagesBase}/${spaName}"
String vmBase = "spark/spark-spa/src/main/resources/velocity/${spaName}"
String mountPoint = "${project(':server').webAppDir}/WEB-INF/rails/webpack/single_page_apps"
project.delete(modelsBase, widgetBase, vmBase)
project.mkdir(modelsBase)
project.mkdir(widgetBase)
project.mkdir(vmBase)
String licenseHeader =
"""
* Copyright ${project.copyrightYear} ThoughtWorks, Inc.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
""".stripIndent().trim()
String javaOrJavaScriptLicencseHeader = "/*\n${licenseHeader.split('\n').collect { eachLine -> " ${eachLine}" }.join("\n")}\n */\n\n"
file("${mountPoint}/${spaName}.tsx").withWriter { out ->
def contents =
"""
import {SinglePageAppBase} from "helpers/spa_base";
import {${entityName}Page} from "views/pages/${spaName}";
export class ${entityName}SPA extends SinglePageAppBase {
constructor() {
super(${entityName}Page);
}
}
//tslint:disable-next-line
new ${entityName}SPA();
"""
out.println(javaOrJavaScriptLicencseHeader + contents.stripIndent().trim())
}
file("${pagesBase}/${spaName}.tsx").withWriter { out ->
def contents =
"""
import m from "mithril";
import {${entityName}} from "models/${spaName}/${spaName}";
import {${entityName}Widget} from "views/pages/${spaName}/${spaName}_widget";
import {Page} from "views/pages/page";
interface State {
dummy?: ${entityName};
}
export class ${entityName}Page extends Page<null, State> {
componentToDisplay(vnode: m.Vnode<null, State>): m.Children {
return <${entityName}Widget/>;
}
pageName(): string {
return "SPA Name goes here!";
}
fetchData(vnode: m.Vnode<null, State>): Promise<any> {
// to be implemented
return Promise.resolve();
}
}
"""
out.println(javaOrJavaScriptLicencseHeader + contents.stripIndent().trim())
}
file("${widgetBase}/${spaName}_widget.tsx").withWriter { out ->
def contents =
"""
import {MithrilViewComponent} from "jsx/mithril-component";
import m from "mithril";
import {${entityName}} from "models/${spaName}/${spaName}";
interface Attrs {
dummy?: ${entityName};
}
export class ${entityName}Widget extends MithrilViewComponent<Attrs> {
view(vnode: m.Vnode<Attrs>) {
return <div> This is widget</div>;
}
}
"""
out.println(javaOrJavaScriptLicencseHeader + contents.stripIndent().trim())
}
file("${modelsBase}/${spaName}.ts").withWriter { out ->
def contents =
"""
interface EmbeddedJSON {
dummy?: boolean;
// to be implemented
}
interface ${entityName}JSON {
_embedded: EmbeddedJSON;
}
export class ${entityName} {
// to be implemented
static fromJSON(data: ${entityName}JSON) {
// to be implemented
}
}
"""
out.println(javaOrJavaScriptLicencseHeader + contents.stripIndent().trim())
}
file("spark/spark-spa/src/main/java/com/thoughtworks/go/spark/spa/${entityName}Controller.java").withWriter { out ->
def contents =
"""
package com.thoughtworks.go.spark.spa;
import com.thoughtworks.go.spark.Routes;
import com.thoughtworks.go.spark.SparkController;
import com.thoughtworks.go.spark.spring.SPAAuthenticationHelper;
import spark.ModelAndView;
import spark.Request;
import spark.Response;
import spark.TemplateEngine;
import java.util.HashMap;
import java.util.Map;
import static spark.Spark.*;
public class ${entityName}Controller implements SparkController {
private final SPAAuthenticationHelper authenticationHelper;
private final TemplateEngine engine;
public ${entityName}Controller(SPAAuthenticationHelper authenticationHelper, TemplateEngine engine) {
this.authenticationHelper = authenticationHelper;
this.engine = engine;
}
@Override
public String controllerBasePath() {
return Routes.${entityName}.SPA_BASE;
}
@Override
public void setupRoutes() {
path(controllerBasePath(), () -> {
before("", authenticationHelper::checkAdminUserAnd403);
get("", this::index, engine);
});
}
public ModelAndView index(Request request, Response response) {
Map<Object, Object> object = new HashMap<Object, Object>() {{
put("viewTitle", "${entityName}");
}};
return new ModelAndView(object, null);