elasticsearch.build-complete.gradle

/*
 * Copyright Elasticsearch B.V. and/or licensed to Elasticsearch B.V. under one
 * or more contributor license agreements. Licensed under the Elastic License
 * 2.0 and the Server Side Public License, v 1; you may not use this file except
 * in compliance with, at your election, the Elastic License 2.0 or the Server
 * Side Public License, v 1.
 */

import java.nio.file.Files

String buildNumber = System.getenv('BUILD_NUMBER')
String performanceTest = System.getenv('BUILD_PERFORMANCE_TEST')
if (buildNumber && performanceTest == null) {
  File uploadFile = file("build/${buildNumber}.tar.bz2")
  project.gradle.buildFinished { result ->
    println "build complete, generating: $uploadFile"
    if (uploadFile.exists()) {
      project.delete(uploadFile)
    }

    try {
      ant.tar(destfile: uploadFile, compression: "bzip2", longfile: "gnu") {
        fileset(dir: projectDir) {
          Set<File> fileSet = fileTree(projectDir) {
            include("**/*.hprof")
            include("**/build/test-results/**/*.xml")
            include("**/build/testclusters/**")
            exclude("**/build/testclusters/**/data/**")
            exclude("**/build/testclusters/**/distro/**")
            exclude("**/build/testclusters/**/repo/**")
            exclude("**/build/testclusters/**/extract/**")
          }
            .files
            .findAll { Files.isRegularFile(it.toPath()) }

          if (fileSet.empty) {
            // In cases where we don't match any workspace files, exclude everything
            ant.exclude(name: "**/*")
          } else {
            fileSet.each {
              ant.include(name: projectDir.toPath().relativize(it.toPath()))
            }
          }
        }

        fileset(dir: "${gradle.gradleUserHomeDir}/daemon/${gradle.gradleVersion}", followsymlinks: false) {
          include(name: "**/daemon-${ProcessHandle.current().pid()}*.log")
        }

        fileset(dir: "${gradle.gradleUserHomeDir}/workers", followsymlinks: false)

        fileset(dir: "${project.projectDir}/.gradle/reaper", followsymlinks: false, erroronmissingdir: false)
      }
    } catch (Exception e) {
      logger.lifecycle("Failed to archive additional logs", e)
    }
  }
}