build.gradle

/*
 * Copyright 2022 Grabtaxi Holdings PTE LTD (GRAB)
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */


import com.android.build.gradle.BaseExtension

buildscript {
    apply from: "constants.gradle"
}
plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.kapt) apply false
    alias(libs.plugins.kotlin.parcelize) apply false
    alias(libs.plugins.google.mobile.services) apply false
    alias(libs.plugins.firebase.crashlytics) apply false
    id "idea"
    id "com.grab.grazel"
}

allprojects {
    // TODO(arun) Add support for repository in settings.gradle and then remove this
    repositories {
        google()
        mavenCentral()
    }
    group groupId
    version versionName

    configurations.configureEach {
        resolutionStrategy {
            // Force a dependency to test if Grazel picks it up correctly.
            force "com.google.dagger:dagger:2.47"
            force "com.google.dagger:dagger-compiler:2.47"
        }
    }

    // TODO(arun) Move these to convention plugins
    plugins.withType(com.android.build.gradle.BasePlugin).configureEach { plugin ->
        (project.extensions.getByName("android") as BaseExtension).with {
            compileOptions {
                sourceCompatibility = JavaVersion.VERSION_11
                targetCompatibility = JavaVersion.VERSION_11
            }
            lint {
                lintConfig = rootProject.file("lint.xml")
            }
        }
    }

    tasks.withType(JavaCompile).configureEach { task ->
        task.sourceCompatibility = JavaVersion.VERSION_11
        task.targetCompatibility = JavaVersion.VERSION_11
    }

    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompilationTask.class).configureEach {
        compilerOptions.jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_11)
        compilerOptions.languageVersion = org.jetbrains.kotlin.gradle.dsl.KotlinVersion.KOTLIN_1_7
    }
}

tasks.named("wrapper") {
    gradleVersion = libs.versions.gradle.wrapper.get()
    distributionType = Wrapper.DistributionType.ALL
}

grazel {
    android {
        // dexShards = 5
        multiDexEnabled = true
        incrementalDexing = true
        variantFilter { variant ->
            variant.setIgnore(variant.buildType.name != "debug")
        }
        features {
            dataBindingMetaData = true
        }
        ndkApiLevel = 30
    }
    dependencies {
        overrideArtifactVersions.addAll(
            //"androidx.constraintlayout:constraintlayout:2.1.4",
        )
    }
    rules {
        bazelCommon {
            gitRepository {
                commit = "b3ced63a493c8990e1ab410e645111aa25fb7df7"
                remote = "https://github.com/grab/grab-bazel-common.git"
            }
            toolchains {
                buildifier {
                    releaseVersion = "6.3.3"
                    supportedOs = ["linux", "darwin"]
                    supportedArch = ["amd64", "arm64"]
                }
            }
        }
        googleServices {
            crashlytics {
                buildId = "042cb4d8-56f8-41a0-916a-9da28e94d1ba"
            }
            gitRepository {
                commit = "7224f55d7fafe12a72066eb1a2ad1e1526a854c4"
                remote = "https://github.com/bazelbuild/tools_android.git"
            }
        }
        mavenInstall {
             httpArchiveRepository {
                sha256 = "d31e369b854322ca5098ea12c69d7175ded971435e55c18dd9dd5f29cc5249ac"
                stripPrefix = "rules_jvm_external-5.3"
                url = String.format("https://github.com/bazelbuild/rules_jvm_external/releases/download/%s/rules_jvm_external-%s.tar.gz", "5.3", "5.3")
            }
            includeCredentials = false
            resolveTimeout = 1000
            excludeArtifactsDenyList.add("androidx.constraintlayout:constraintlayout-core")
            excludeArtifacts.add("androidx.test.espresso:espresso-contrib")

            // Force add any artifact for jetifier
            jetifyIncludeList.addAll(
                "com.android.support:cardview-v7",
                "com.android.support:support-annotations",
                "com.android.support:support-compat",
                "com.android.support:support-core-ui",
                "com.android.support:support-core-utils",
            )

            artifactPinning {
                enabled.set(true)
            }

            overrideTargetLabels.putAll(
                // Workaround for https://issuetracker.google.com/issues/285353844
                ["androidx.annotation:annotation": "@maven//:androidx_annotation_annotation_jvm"]
            )
            versionConflictPolicy = "pinned"
        }
        kotlin {
            httpArchiveRepository {
                url = "https://github.com/bazelbuild/rules_kotlin/releases/download/v1.9.5/rules_kotlin-v1.9.5.tar.gz"
                sha256 = "34e8c0351764b71d78f76c8746e98063979ce08dcf1a91666f3f3bc2949a533d"
            }
            compiler {
                tag = "1.8.10"
                sha = "4c3fa7bc1bb9ef3058a2319d8bcc3b7196079f88e92fdcd8d304a46f4b6b5787"
            }
            toolchain {
                enabled = true
                apiVersion = "1.7"
                reportUnusedDeps = "off"
                strictKotlinDeps = "off"
                abiJars = true
                multiplexWorkers = true
                languageVersion = "1.7"
                jvmTarget = "11"
            }
        }
        dagger {
            tag = "2.47"
            sha = "154cdfa4f6f552a9873e2b4448f7a80415cb3427c4c771a50c6a8a8b434ffd0a"
        }
    }
}

idea {
    module {
        excludeDirs += [
            file("bazel-bin"),
            file("bazel-grazel"),
            file("bazel-cache"),
            file("bazel-out"),
            file("bazel-testlogs"),
        ]
    }
}