Custom Check Not Effective in Bazel

[xingyutangyuan]

I'm trying to create a custom check using bazel. The following are my BUILD file:

java_library(
    name = "custom",
    srcs = glob(["src/main/java/**/*.java"]),
    visibility = ["//visibility:public"],
    add_exports = JDK_COMPILER_ADD_EXPORTS,
    deps = [
        "@maven//:com_google_auto_service_auto_service_annotations",
        "@maven//:com_google_errorprone_error_prone_core",
        "@maven//:com_google_errorprone_error_prone_annotation",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_errorprone_error_prone_check_api",
        "@maven//:com_google_errorprone_error_prone_docgen_processor",
        "@maven//:com_google_guava_guava",
        "//mug:base",
        "//mug-guava",
    ],
    plugins = [
        "@maven//:com_google_auto_service_auto_service",
    ],
    exports = [
        "@maven//:com_google_errorprone_error_prone_core",
        "@maven//:com_google_auto_service_auto_service",
    ],
)

java_plugin(
    name = "plugin",
    processor_class = "com.google.auto.service.processor.AutoServiceProcessor",
    visibility = ["//visibility:public"],
    deps = [":custom"],
)

When I include the plugins = ["@maven//:com_google_auto_service_auto_service"] line, I get this error:

'@maven//:com_google_auto_service_auto_service' does not have mandatory providers: 'JavaPluginInfo'

If I leave it out, the generated plugin.jar includes only MANIFEST file:

    0 Fri Jan 01 00:00:00 PST 2010 META-INF/
    83 Fri Jan 01 00:00:00 PST 2010 META-INF/MANIFEST.MF

And the MANIFEST file's content:

Manifest-Version: 1.0
Created-By: bazel
Target-Label: //mug-errorprone:plugin

The tests using CompilationTestHelper all pass correctly (detecting errors). But the plugin when used in another java_library as exported_plugins doesn't detect any error as if no check is performed.

What am I missing?

[cushon]

The library that defines the custom check needs to depend on the java_plugin for AutoService, and then there needs to be a separate java_plugin rule for the custom check.

Here's a demo:

java_library(
    name = "demo",
    srcs = ["src/main/java/com/example/Demo.java"],
    plugins = [":my_custom_check"],
)

java_plugin(
    name = "my_custom_check",
    srcs = ["src/main/java/com/example/MyCustomCheck.java"],
    deps = [
        ":auto_service",
        "@maven//:com_google_errorprone_error_prone_annotation",
        "@maven//:com_google_errorprone_error_prone_check_api",
    ],
)

java_library(
    name = "auto_service",
    exported_plugins = [
        ":auto_service_plugin",
    ],
    exports = [
        "@maven//:com_google_auto_service_auto_service_annotations",
    ],
)

java_plugin(
    name = "auto_service_plugin",
    processor_class = "com.google.auto.service.processor.AutoServiceProcessor",
    deps = [
        "@maven//:com_google_auto_service_auto_service",
    ],
)

$ bazel build :demo
src/main/java/com/example/Demo.java:5: error: [MyCustomCheck] This is a return statement
    return;
    ^

[xingyutangyuan]

Thank you cushon!

I followed your example and was able to trigger a compilation error!

What I did wrong(?) was to wrap the custom checks in a separate java_library (so that the tests can depend on it instead of the java_plugin):

java_library(
    name = "my_custom_check_lib",
    srcs = ["src/main/java/com/example/MyCustomCheck.java"],
    deps = [
        "@maven//:com_google_errorprone_error_prone_annotation",
        "@maven//:com_google_errorprone_error_prone_check_api",
    ],
)

java_plugin(
    name = "my_custom_check",
    deps = [
        ":auto_service",
        ":my_custom_check_lib",
        "@maven//:com_google_errorprone_error_prone_annotation",
        "@maven//:com_google_errorprone_error_prone_check_api",
    ],
)

But that extra java_plugin -> java_library wrapping somehow defeated the check.

Is there a legit pattern to both enable the check and make the plugin testable? If I have the test target depend on the plugin, I got build errors.

[cushon]

Is there a legit pattern to both enable the check and make the plugin testable?

The usual approach is having a java_library for the check, and then having a separate java_plugin that depends on that library, and having the test depend directly on the library.

Your snippet looks close, but I think you need my_custom_check_lib to include the AutoService deps, and the only dependency of my_custom_check should by my_custom_check_lib.

java_library(
    name = "my_custom_check_lib",
    srcs = ["src/main/java/com/example/MyCustomCheck.java"],
    deps = [
+        ":auto_service",
        "@maven//:com_google_errorprone_error_prone_annotation",
        "@maven//:com_google_errorprone_error_prone_check_api",
    ],
)

java_plugin(
    name = "my_custom_check",
    deps = [
-        ":auto_service",
        ":my_custom_check_lib",
    ],
)

[xingyutangyuan]

Thank you cushon! Works beautifully!