-
-
Notifications
You must be signed in to change notification settings - Fork 427
/
build.gradle.kts
161 lines (136 loc) · 4.22 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
import com.android.build.gradle.internal.tasks.LibraryAarJarsTask
import io.gitlab.arturbosch.detekt.Detekt
import org.jetbrains.dokka.gradle.DokkaTask
plugins {
kotlin("multiplatform")
id("com.android.library")
id("org.jetbrains.compose")
jacoco
id(Config.QualityPlugins.gradleVersions)
id(Config.QualityPlugins.detektPlugin)
id(Config.BuildPlugins.dokkaPluginAlias)
`maven-publish` // necessary for publishMavenLocal task to publish correct artifacts
}
kotlin {
explicitApi()
android {
publishLibraryVariants("release")
}
jvm() {
compilations.all {
kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8.toString()
}
}
sourceSets.all {
// Allow all experimental APIs, since MPP projects are themselves experimental
languageSettings.apply {
optIn("kotlin.Experimental")
optIn("kotlin.ExperimentalMultiplatform")
}
}
sourceSets {
val commonMain by getting {
dependencies {
api(compose.runtime)
api(compose.ui)
implementation(Config.Libs.kotlinStdLib)
}
}
val jvmMain by getting {
dependencies {
api(projects.sentry)
implementation(Config.Libs.kotlinStdLib)
api(projects.sentryComposeHelper)
}
}
val androidMain by getting {
dependsOn(jvmMain)
dependencies {
api(projects.sentryAndroidNavigation)
api(Config.Libs.composeNavigation)
implementation(Config.Libs.lifecycleCommonJava8)
}
}
val androidTest by getting {
dependencies {
implementation(Config.TestLibs.kotlinTestJunit)
implementation(Config.TestLibs.mockitoKotlin)
implementation(Config.TestLibs.mockitoInline)
}
}
}
}
android {
compileSdk = Config.Android.compileSdkVersion
namespace = "io.sentry.compose"
defaultConfig {
targetSdk = Config.Android.targetSdkVersion
minSdk = Config.Android.minSdkVersionCompose
// for AGP 4.1
buildConfigField("String", "VERSION_NAME", "\"${project.version}\"")
}
sourceSets["main"].apply {
manifest.srcFile("src/androidMain/AndroidManifest.xml")
}
buildTypes {
getByName("debug")
getByName("release") {
consumerProguardFiles("proguard-rules.pro")
}
}
testOptions {
animationsDisabled = true
unitTests.apply {
isReturnDefaultValues = true
isIncludeAndroidResources = true
}
}
lint {
warningsAsErrors = true
checkDependencies = true
// We run a full lint analysis as build part in CI, so skip vital checks for assemble tasks.
checkReleaseBuilds = false
}
variantFilter {
if (Config.Android.shouldSkipDebugVariant(buildType.name)) {
ignore = true
}
}
}
tasks.withType<Test> {
configure<JacocoTaskExtension> {
isIncludeNoLocationClasses = false
}
}
tasks.withType<Detekt> {
// Target version of the generated JVM bytecode. It is used for type resolution.
jvmTarget = JavaVersion.VERSION_1_8.toString()
}
tasks.withType<DokkaTask>().configureEach {
// suppress unattached source sets for docs
dokkaSourceSets {
matching {
it.name.contains("androidandroid", ignoreCase = true) ||
it.name.contains("testfixtures", ignoreCase = true)
}.configureEach {
suppress.set(true)
}
}
}
/**
* Due to https://youtrack.jetbrains.com/issue/KT-30878
* you can not java sources in a KMP-enabled project which has the android-lib plugin applied.
* Thus we compile relevant java code in sentry-compose-helper first and embed it in here.
*/
val embedComposeHelperConfig by configurations.creating {
isCanBeConsumed = false
isCanBeResolved = true
}
dependencies {
embedComposeHelperConfig(
project(":" + projects.sentryComposeHelper.name, "embeddedJar")
)
}
tasks.withType<LibraryAarJarsTask> {
mainScopeClassFiles.setFrom(embedComposeHelperConfig)
}