Android example

[Malachiasz]

Please provide a sample showing what is possible on Android.

[lukehutch]

Android does not use classfiles at time of deployment, therefore ClassGraph cannot be used. However, ClassGraph can be used at build time in Android projects, before the compiled code is converted from Java bytecodes to Dalvik bytecodes. This is documented here:

https://github.com/classgraph/classgraph/wiki/Build-Time-Scanning

[Malachiasz]

I have found it after asking the question here. The sample did not compile I had to modify it:

afterEvaluate { project ->
    // Get some task references
    def compileTask = project.tasks.compileDebugJavaWithJavac
    def mergeTask = project.tasks.mergeDebugResources

    compileTask.doLast {
        // [Set your parameters here]
        def packageToScan = "my.project"
        def scanResultFilename = "scan_result.txt"

        // Create a temporary raw resource directory for saving the scan result to
        def scanResultDir = compileTask.temporaryDir.toString() + "/res/raw/"
        new File(scanResultDir).mkdirs()
        def scanResultPath = scanResultDir + scanResultFilename

        // Get location where .class files were compiled to
        def classPackageRoot = compileTask.destinationDir

        println "Scanning " + classPackageRoot
        new io.github.classgraph.ClassGraph()
        // [Configure your ClassGraph instance here]
                .overrideClasspath(classPackageRoot)
                .whitelistPackages(packageToScan)
                .enableAllInfo()
        // .verbose()
                .scan()
                .withCloseable { scanResult ->
                    // [Get the scan results you're interested in here]
                    def resultList = scanResult.getAllClasses()
                    // Write the results to the output file
                    def outputFile = new File(scanResultPath)
                    outputFile.withWriter { writer ->
                        resultList.each { ci ->
                            // Write name of annotated class to output file
                            writer.println ci.getName()
                        }
                    }
                    println "Wrote scan result to " + outputFile +" ; size = " + outputFile.length()
                }

        // Run AAPT2 to convert the raw resource file into a .flat file
        def aapt2Path = "/Users/user/Library/Android/sdk/build-tools/30.0.0/aapt2" // change it to your path
        def flatFileOutputPrefix = mergeTask.outputDir.toString() + "/"
        def cmd = [aapt2Path, "compile", "-o", flatFileOutputPrefix, scanResultPath]
        println "Executing: " + cmd.join(" ")
        def exec = cmd.execute()
        exec.in.eachLine { line -> println line }
        exec.err.eachLine { line -> System.err.println "ERROR: " + line }
        exec.waitFor()
        println "Wrote compiled resource as a .flat file to " + flatFileOutputPrefix
    }
}

That's why it's better to have a sample on github with gradle version java version and everything else specified.

Also I see it cannot access files not in my sources.

[lukehutch]

It used to work, so probably Gradle or Android changed, or something... and the same exact bitrot can happen just as easily with sample projects. I don't actively work on Android anymore, as of several years ago. You are welcome to set up your own example project on GitHub for people to discover. But honestly there seems to be very little demand for scanning classes in Android projects -- I get about one question per year about this.

I can update the build-time scanning page though. Thanks for the working example!

[lukehutch]

Sorry, that sounds like a Gradle question, and I have no idea. Maybe try asking about this error message on a Gradle forum?

[thc202]

You most likely need to do mergeTask.outputDir.get().toString(), it seems that now the outputDir is a Property so you need to get its value before converting to string.

[HashirLabs]

Thanks, this worked now

I also want to add that after this i was facing invalid path issue on windows machine, i had to update below line which fixed it and now its working perfectly.

old
def scanResultDir = compileTask.temporaryDir.toString() + "/res/raw/"

New
def scanResultDir = compileTask.temporaryDir.toString() + "\\res\\raw\\"

Now, i am wondering if there is a way to provide the aapt path via gradle constants rather than hardcoded path, as this path gets updated as and when we update android build tool

something like def aapt2Path = mergeTask.buildTools.getPath(com.android.sdklib.BuildToolInfo.PathId.AAPT2) which does not work at the moment

instead of def aapt2Path = "D:/IT/Android/sdk/build-tools/33.0.1/aapt2" /

many thanks for the help anywayz

[lukehutch]

@HashirLabs thanks, I updated the docs to use File.separator.

I don't do any low-level Android build stuff anymore, so I can't help with the aapt2 path, but if you figure it out, let me know, and I'll update the docs again. Thanks!

[lukehutch]

@thc202 Thanks for the fix, I updated the wiki with your suggested change

[HashirLabs]

@lukehutch

i have updated my gradle script to pick the aapt2 dynamically based on user's sdk directory, now the manual path setup is not required, below is tested and found working, you can update the wiki accordingly

    def aapt2Path = android.getSdkDirectory().toPath().resolve("build-tools").resolve(android.buildToolsVersion).resolve("aapt2")

[lukehutch]

@HashirLabs Nice work! Thanks, I updated the wiki.