-
Notifications
You must be signed in to change notification settings - Fork 496
/
build.gradle
163 lines (141 loc) · 5.65 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
import org.jetbrains.kotlin.konan.target.HostManager
plugins {
alias(libs.plugins.kotlin.jvm)
alias(libs.plugins.shadow) apply false
alias(libs.plugins.publish)
alias(libs.plugins.dokka)
id("java-gradle-plugin")
id("jvm-test-suite")
}
testing {
suites {
dockerTest(JvmTestSuite) {
useJUnit()
}
}
}
configurations.dockerTestImplementation.extendsFrom(configurations.testImplementation)
gradlePlugin {
plugins {
sqlDelight {
id = 'app.cash.sqldelight'
implementationClass = 'app.cash.sqldelight.gradle.SqlDelightPlugin'
}
}
testSourceSets(sourceSets.test, sourceSets.dockerTest)
}
configurations {
bundled
shade
}
dependencies {
api(libs.sqlPsi) {
exclude group: 'org.jetbrains.kotlin', module: 'kotlin-stdlib-jdk8'
}
implementation libs.sqliteJdbc
implementation libs.objectDiff
implementation libs.schemaCrawler.tools
implementation libs.schemaCrawler.sqlite
shade project(':sqlite-migrations')
shade project(':sqldelight-compiler')
shade libs.intellij.analysis
shade libs.intellij.core
shade libs.intellij.java
shade libs.intellij.lang
shade libs.intellij.testFramework
compileOnly gradleApi()
implementation libs.kotlin.plugin
compileOnly libs.android.plugin
testImplementation libs.sqlPsi
testImplementation project(':sqlite-migrations')
testImplementation project(':sqldelight-compiler')
testImplementation libs.junit
testImplementation libs.truth
testImplementation libs.testParameterInjector
}
tasks.named('test') {
// The integration tests require local installations of artifacts.
dependsOn(
":dialects:mysql:publishAllPublicationsToInstallLocallyRepository",
":dialects:hsql:publishAllPublicationsToInstallLocallyRepository",
":dialects:postgresql:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite:json-module:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-18:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-24:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-25:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-30:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-35:publishAllPublicationsToInstallLocallyRepository",
":dialects:sqlite-3-38:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-compiler:dialect:publishAllPublicationsToInstallLocallyRepository",
":runtime:publishKotlinMultiplatformPublicationToInstallLocallyRepository",
":runtime:publishJvmPublicationToInstallLocallyRepository",
":runtime:publishJsPublicationToInstallLocallyRepository",
":drivers:android-driver:publishAllPublicationsToInstallLocallyRepository",
":drivers:sqlite-driver:publishAllPublicationsToInstallLocallyRepository",
":drivers:jdbc-driver:publishAllPublicationsToInstallLocallyRepository",
":sqlite-migrations:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-compiler:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-gradle-plugin:publishAllPublicationsToInstallLocallyRepository",
)
if (HostManager.hostIsMac) {
dependsOn(
":drivers:native-driver:publishIosX64PublicationToInstallLocallyRepository",
":drivers:native-driver:publishIosSimulatorArm64PublicationToInstallLocallyRepository",
":drivers:native-driver:publishKotlinMultiplatformPublicationToInstallLocallyRepository",
":runtime:publishIosX64PublicationToInstallLocallyRepository",
":runtime:publishIosSimulatorArm64PublicationToInstallLocallyRepository",
":runtime:publishIosArm64PublicationToInstallLocallyRepository",
)
}
useJUnit {
if (project.hasProperty("Instrumentation")) {
includeCategories 'app.cash.sqldelight.Instrumentation'
} else {
excludeCategories 'app.cash.sqldelight.Instrumentation'
}
}
}
tasks.named('check') {
dependsOn(testing.suites.dockerTest)
}
tasks.named('dockerTest') {
if (project.hasProperty("Instrumentation")) enabled = false
dependsOn(
":dialects:mysql:publishAllPublicationsToInstallLocallyRepository",
":dialects:postgresql:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-compiler:dialect:publishAllPublicationsToInstallLocallyRepository",
":runtime:publishKotlinMultiplatformPublicationToInstallLocallyRepository",
":runtime:publishJvmPublicationToInstallLocallyRepository",
":drivers:jdbc-driver:publishAllPublicationsToInstallLocallyRepository",
":sqlite-migrations:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-compiler:publishAllPublicationsToInstallLocallyRepository",
":sqldelight-gradle-plugin:publishAllPublicationsToInstallLocallyRepository",
":drivers:r2dbc-driver:publishAllPublicationsToInstallLocallyRepository",
":extensions:async-extensions:publishAllPublicationsToInstallLocallyRepository",
)
}
tasks.named('validatePlugins') {
enableStricterValidation = true
}
if (System.getenv("CI") == "true") {
apply plugin: 'com.github.johnrengelman.shadow'
configurations.compileOnly.extendsFrom(configurations.shade)
tasks.named("shadowJar") {
archiveClassifier.set("")
minimize()
configurations = [project.configurations.shade]
include '*.jar'
include '**/*.class'
include 'META-INF/gradle-plugins/*'
include 'messages/*.properties'
exclude '/groovy**'
exclude '/kotlin/**'
}
artifacts {
runtimeOnly(tasks.named('shadowJar'))
archives(tasks.named('shadowJar'))
}
} else {
configurations.implementation.extendsFrom(configurations.shade)
}
apply from: "$rootDir/gradle/gradle-mvn-push.gradle"