-
Notifications
You must be signed in to change notification settings - Fork 427
/
hackney_response.erl
375 lines (337 loc) · 13 KB
/
hackney_response.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
%%% -*- erlang -*-
%%%
%%% This file is part of hackney released under the Apache 2 license.
%%% See the NOTICE for more information.
%%%
%% @doc module handling the response
-module(hackney_response).
-include("hackney.hrl").
-include("hackney_lib.hrl").
-type response_state() :: start | waiting | on_status | on_headers | on_body.
-export_type([response_state/0]).
-export([start_response/1,
stream_body/1,
stream_multipart/1,
skip_multipart/1,
body/1, body/2, skip_body/1,
maybe_close/1,
close/1,
expect_response/1]).
%% internal
%% @doc Start the response It parse the request lines and headers.
start_response(#client{response_state=stream, mp_boundary=nil} = Client) ->
case hackney_request:end_stream_body(Client) of
{ok, Client1} ->
start_response(Client1);
Error ->
Error
end;
start_response(#client{response_state=stream} = Client) ->
case hackney_request:stream_multipart(eof, Client) of
{ok, Client1} ->
start_response(Client1);
Error ->
Error
end;
start_response(#client{request_ref=Ref, response_state=waiting,
async=Async}=Client)
when Async =:= true orelse Async =:= once ->
hackney_manager:update_state(Client),
case hackney_manager:start_async_response(Ref) of
ok ->
{ok, Ref};
Error ->
Error
end;
start_response(#client{response_state=waiting} = Client) ->
Parser = hackney_http:parser([response]),
wait_status(Client#client{parser=Parser});
start_response(_) ->
{error, invalide_state}.
%% @doc handle Expect header
expect_response(Client) ->
case recv(Client#client{recv_timeout=1000}) of
{ok, <<"HTTP/1.1 100 Continue\r\n\r\n" , Rest/binary >>} ->
{continue, Client#client{expect=false, buffer=Rest}};
{ok, Data} ->
{stop, Client#client{buffer=Data, expect=false,
response_state=waiting}};
{error, timeout} ->
{continue, Client#client{expect=false}};
Error ->
Error
end.
wait_status(#client{buffer=Buf, parser=Parser}=Client) ->
case hackney_http:execute(Parser, Buf) of
{more, NParser} ->
case recv(Client) of
{ok, Data} ->
wait_status(Client#client{buffer=Data,
parser=NParser});
Error ->
Error
end;
{response, Version, Status, _Reason, NParser} ->
wait_headers(Client#client{parser=NParser,
buffer = <<>>,
version=Version}, Status);
Error ->
Error
end.
wait_headers(#client{parser=Parser}=Client, Status) ->
wait_headers(hackney_http:execute(Parser), Client, Status, hackney_headers_new:new()).
wait_headers({more, Parser}, Client, Status, Headers) ->
case recv(Client) of
{ok, Data} ->
wait_headers(hackney_http:execute(Parser, Data), Client, Status,
Headers);
Error ->
Error
end;
wait_headers({header, {Key, Value}, Parser}, Client, Status, Headers) ->
Headers2 = hackney_headers_new:append(Key, Value, Headers),
wait_headers(hackney_http:execute(Parser), Client, Status, Headers2);
wait_headers({headers_complete, Parser}, Client, Status, Headers) ->
ResponseTime = timer:now_diff(os:timestamp(),
Client#client.start_time)/1000,
_ = metrics:update_histogram(Client#client.mod_metrics,
[hackney, Client#client.host, response_time],
ResponseTime),
HeadersList = hackney_headers_new:to_list(Headers),
TE = hackney_headers_new:get_value(<<"transfer-encoding">>, Headers, nil),
CLen = case hackney_headers_new:lookup("content-length", Headers) of
[] -> undefined;
[{_, Len} |_] ->
case hackney_util:to_int(Len) of
{ok, I} -> I;
false -> bad_int
end
end,
Client2 = Client#client{parser=Parser,
headers=Headers,
te=TE,
clen=CLen},
{ok, Status, HeadersList, Client2}.
stream_body(Client=#client{response_state=done}) ->
{done, Client};
stream_body(Client=#client{method= <<"HEAD">>, parser=Parser}) ->
Buffer = hackney_http:get(Parser, buffer),
Client2 = end_stream_body(Buffer, Client),
{done, Client2};
stream_body(Client=#client{parser=Parser, clen=CLen, te=TE}) ->
case {TE, CLen} of
{<<"chunked">>, _} ->
stream_body1(hackney_http:execute(Parser), Client);
{_, CLen} when CLen =:= 0 orelse CLen =:= bad_int ->
Buffer = hackney_http:get(Parser, buffer),
Client2 = end_stream_body(Buffer, Client),
{done, Client2};
{_, _} ->
stream_body1(hackney_http:execute(Parser), Client)
end.
stream_body(Data, #client{parser=Parser}=Client) ->
stream_body1(hackney_http:execute(Parser, Data), Client).
stream_body1({more, Parser}, Client) ->
stream_body_recv(<<>>, Client#client{parser=Parser});
stream_body1({more, Parser, Buffer}, Client) ->
stream_body_recv(Buffer, Client#client{parser=Parser});
stream_body1({ok, Data, Parser}, Client) ->
{ok, Data, Client#client{parser=Parser}};
stream_body1({done, Rest}, Client) ->
Client2 = end_stream_body(Rest, Client),
{done, Client2};
stream_body1(done, Client) ->
Client2 = end_stream_body(<<>>, Client),
{done, Client2};
stream_body1(Error, _Client) ->
Error.
-spec stream_body_recv(binary(), #client{})
-> {ok, binary(), #client{}} | {error, term()}.
stream_body_recv(Buffer, Client=#client{parser=#hparser{body_state={stream, _, TransferState, _}}}) ->
case recv(Client, TransferState) of
{ok, Data} ->
stream_body(Data, Client);
{error, Reason} ->
stream_body_recv_error(Reason, Buffer, Client)
end;
stream_body_recv(Buffer, Client=#client{parser=#hparser{body_state=done}}) ->
case recv(Client) of
{ok, Data} ->
stream_body(Data, Client);
{error, Reason} ->
stream_body_recv_error(Reason, Buffer, Client)
end.
stream_body_recv_error(Reason, Buffer, Client=#client{version=Version, clen=CLen}) ->
Client2 = close(Client),
case Reason of
closed when (Version =:= {1, 0} orelse Version =:= {1, 1}) andalso (CLen =:= nil orelse CLen =:= undefined) ->
{ok, Buffer, Client2#client{response_state=done,
body_state=done,
buffer = <<>>,
parser=nil}};
closed when Client#client.te =:= <<"identity">> ->
{ok, Buffer, Client2#client{response_state=done,
body_state=done,
buffer = <<>>}};
closed ->
{error, {closed, Buffer}};
_Else ->
{error, Reason}
end.
%% @doc stream a multipart response
%%
%% Use this function for multipart streaming. For each part in the
%% response, this function returns <em>{headers, Headers, Req}</em> followed by a sequence of
%% <em>{body, Data, Req}</em> tuples and finally <em>{end_of_part, Req}</em>. When there
%% is no part to parse anymore, <em>{eof, Req}</em> is returned.
-spec stream_multipart(#client{})
-> {headers, list(), #client{}} | {body, binary(), #client{}}
| {eof|end_of_part|mp_mixed|mp_mixed_eof, #client{}}.
stream_multipart(Client=#client{headers=Headers, body_state=waiting, clen=Length}) ->
CType = hackney_headers_new:get_value(<<"content-type">>, Headers),
{<<"multipart">>, _, Params} = hackney_headers_new:parse_content_type(CType),
{_, Boundary} = lists:keyfind(<<"boundary">>, 1, Params),
Parser = hackney_multipart:parser(Boundary),
multipart_data(Client#client{body_state=processing}, Length,
{more, Parser});
stream_multipart(Client=#client{multipart={Length, Cont}}) ->
multipart_data(Client, Length, Cont());
stream_multipart(Client=#client{body_state=done}) ->
{eof, Client}.
multipart_data(Client, Length, {headers, Headers, Cont}) ->
{headers, Headers, Client#client{multipart={Length, Cont}}};
multipart_data(Client, Length, {body, Data, Cont}) ->
{body, Data, Client#client{multipart={Length, Cont}}};
multipart_data(Client, Length, {end_of_part, Cont}) ->
{end_of_part, Client#client{multipart={Length, Cont}}};
multipart_data(Client, Length, {mp_mixed, Cont}) ->
{mp_mixed, Client#client{multipart={Length, Cont}}};
multipart_data(Client, Length, {mp_mixed_eof, Cont}) ->
{mp_mixed_eof, Client#client{multipart={Length, Cont}}};
multipart_data(Client, Length, eof)
when Length =:= 0 orelse Length =:= nil orelse Length =:= undefined ->
Client2 = end_stream_body(<<>>, Client),
{eof, Client2#client{body_state=done, multipart=nil}};
multipart_data(Client, _, eof) ->
%% We just want to skip so no need to stream data here.
{skip, Client2} = skip_body(Client),
{eof, Client2#client{multipart=nil}};
multipart_data(Client, Length, {more, Parser})
when Length > 0 orelse Length =:= nil orelse Length =:= undefined ->
case stream_body(Client) of
{ok, Data, Client2} when Length =:= nil ->
multipart_data(Client2, Length, Parser(Data));
{ok, Data, Client2} when Length =:= undefined ->
multipart_data(Client2, Length, Parser(Data));
{ok, << Data:Length/binary, Buffer/binary >>, Client2} ->
multipart_data(Client2#client{buffer=Buffer}, 0,
Parser(Data));
{ok, Data, Client2} ->
multipart_data(Client2, Length - byte_size(Data),
Parser(Data))
end.
%% @doc Skip a part returned by the multipart parser.
%%
%% This function repeatedly calls <em>multipart_data/1</em> until
%% <em>{end_of_part, Req}</em> or <em>{eof, Req}</em> is parsed.
-spec skip_multipart(Client) -> {ok, Client} when Client::#client{}.
skip_multipart(Client) ->
case stream_multipart(Client) of
{end_of_part, Client2} -> {ok, Client2};
{eof, Client2} -> {ok, Client2};
{_, _, Client2} -> skip_multipart(Client2)
end.
%% @doc Return the full body sent with the request.
-spec body(#client{}) -> {ok, binary(), #client{}} | {error, atom()}.
body(Client) ->
read_body(infinity, Client, <<>>).
%% @doc Return the full body sent with the request as long as the body
%% length doesn't go over MaxLength.
%%
%% This is most useful to quickly be able to get the full body while
%% avoiding filling your memory with huge request bodies when you're
%% not expecting it.
%%
%% When the response is larger than MaxLength, this function will return
%% the body it received up to the last chunk, which might be a bit more than MaxLength.
-spec body(non_neg_integer() | infinity, #client{})
-> {ok, binary(), #client{}} | {error, atom()}.
body(MaxLength, Client) ->
read_body(MaxLength, Client, <<>>).
-spec skip_body(#client{}) -> {ok, #client{}} | {skip, #client{}} | {error, atom()}.
skip_body(Client) ->
case stream_body(Client) of
{ok, _, Client2} -> skip_body(Client2);
{done, Client2} -> {skip, Client2};
{error, Reason} -> {error, Reason}
end.
end_stream_body(Rest, Client0) ->
Client = Client0#client{response_state=done,
body_state=done,
parser=nil,
buffer=Rest,
stream_to=false,
async=false},
Pool = hackney_connect:is_pool(Client),
case maybe_close(Client) of
true ->
close(Client);
false when Pool /= false ->
#client{socket=Socket,
socket_ref=Ref,
pool_handler=Handler}=Client,
Handler:checkin(Ref, Socket),
Client#client{state=closed, socket=nil, socket_ref=nil,
buffer = <<>>};
false ->
Client
end.
-spec read_body(non_neg_integer() | infinity, #client{}, binary())
-> {ok, binary(), #client{}} | {error, term()}.
read_body(MaxLength, Client, Acc) when MaxLength > byte_size(Acc) ->
case stream_body(Client) of
{ok, Data, Client2} ->
read_body(MaxLength, Client2, << Acc/binary, Data/binary >>);
{done, Client2} ->
{ok, Acc, Client2};
{error, Reason}=Error ->
case Reason of
{closed, Bin} when is_binary(Bin) ->
{error, {closed, << Acc/binary, Bin/binary >>}};
_ ->
Error
end;
Else ->
{error, Else}
end;
read_body(_MaxLength, Client, Acc) ->
Client2 = end_stream_body(<<>>, Client),
{ok, Acc, Client2}.
maybe_close(#client{socket=nil}) ->
true;
maybe_close(#client{connection= <<"close">>}) ->
true;
maybe_close(#client{version={Min,Maj}, headers=Headers, clen=CLen}) ->
Connection = hackney_bstr:to_lower(
hackney_headers_new:get_value(<<"connection">>, Headers, <<"">>)
),
case Connection of
<<"close">> -> true;
<<"keep-alive">> -> false;
_ when Min =< 0 orelse Maj < 1 -> true;
_ when CLen =:= bad_int -> true;
_ -> false
end.
recv(#client{transport=Transport, socket=Skt, recv_timeout=Timeout}) ->
Transport:recv(Skt, 0, Timeout).
recv(#client{transport=Transport, socket=Skt, recv_timeout=Timeout}, {_BufSize, undefined}) ->
Transport:recv(Skt, 0, Timeout);
recv(#client{transport=Transport, socket=Skt, recv_timeout=Timeout}, {BufSize, ExpectedSize}) when ExpectedSize >= BufSize ->
Transport:recv(Skt, ExpectedSize - BufSize, Timeout);
recv(#client{transport=Transport, socket=Skt, recv_timeout=Timeout}, {_BufSize, _ExpectedSize}) ->
Transport:recv(Skt, 0, Timeout).
close(#client{socket=nil}=Client) ->
Client#client{state = closed};
close(#client{transport=Transport, socket=Skt}=Client) ->
Transport:close(Skt),
Client#client{state = closed, socket=nil}.