-
Notifications
You must be signed in to change notification settings - Fork 280
/
PKGBUILD
52 lines (47 loc) · 1.25 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Hu Butui <hot123tea123@gmail.com>
_pkgname=omegaconf
pkgname=python-omegaconf
pkgver=2.2.3
pkgrel=2
pkgdesc='Flexible Python configuration system'
arch=('any')
license=('BSD')
url='https://github.com/omry/omegaconf'
depends=(
python-antlr4
python-yaml
)
makedepends=(
antlr4
python-build
python-installer
python-setuptools
python-wheel
)
checkdepends=(
python-pytest
python-pytest-benchmark
python-pytest-lazy-fixture
python-pytest-mock
)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/omry/omegaconf/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('9586b6623d4abf514979612f987261971a58da2dc7a9224bebd017848c9ad80a')
prepare() {
# fix antlr jar issue
sed -i 's#str(build_dir / "bin" / "antlr-4.9.3-complete.jar")#"/usr/share/java/antlr-complete.jar"#' ${_pkgname}-${pkgver}/build_helpers/build_helpers.py
}
build() {
cd "${_pkgname}-${pkgver}"
python -m build --wheel --no-isolation
}
check(){
cd "${_pkgname}-${pkgver}"
# we don't have pydev installed, skip it
pytest -v --ignore tests/test_pydev_resolver_plugin.py
}
package() {
cd "${_pkgname}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et: