.qmake.cache.in

# http://qt-project.org/wiki/QMake-top-level-srcdir-and-builddir

top_srcdir=$$PWD
top_builddir=$$OUT_PWD
DESTDIR = $$OUT_PWD

# Note on same-named files:
# There is/was the undocumented object_with_source, object_parallel_to_source,
# but is was removed and/or requires Qt5.
# There is no real sane way to do this, so we dont.
# For mocs, we must do it because it screwes up the source dir otherwise (`$$files(*.cpp)` ...).
# Let's just hope there aren't two equally named moc files.
MOC_DIR=$$OUT_PWD/build/qt/moc


# No mac-scope because of "Using OS scope before setting MAKEFILE_GENERATOR" error from qmake.
uname = $$system(uname)
equals(uname, Darwin) {

	QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.6
	QMAKE_CFLAGS += -isysroot /Developer/SDKs/MacOSX10.7.sdk
	QMAKE_CFLAGS += -mmacosx-version-min=10.6
	QMAKE_CXXFLAGS += -isysroot /Developer/SDKs/MacOSX10.7.sdk
	QMAKE_CXXFLAGS += -mmacosx-version-min=10.6
	QMAKE_CXXFLAGS += -stdlib=libstdc++
	QMAKE_LFLAGS += -isysroot /Developer/SDKs/MacOSX10.7.sdk
	QMAKE_LFLAGS += -mmacosx-version-min=10.6
	QMAKE_LFLAGS += -stdlib=libstdc++

	# maybe also this for libs: -single_module -compatibility_version 1 -current_version 1

	# We use our own Python.
	INCLUDEPATH += $$PWD/python-embedded/CPython/Include
	INCLUDEPATH += $$PWD/python-embedded/pylib

	# For Boost headers.
	# Don't add /usr/local/include because that might confuse Qt if there is another Qt.
	INCLUDEPATH += /usr/local/opt/boost/include

}