forked from mixxxdj/mixxx
-
Notifications
You must be signed in to change notification settings - Fork 0
/
DeveloperToolsWindow.qml
256 lines (205 loc) · 8.65 KB
/
DeveloperToolsWindow.qml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
import "." as Skin
import Mixxx 1.0 as Mixxx
import Qt.labs.qmlmodels 1.0
import QtQuick 2.12
import QtQuick.Controls 2.15
import QtQuick.Layouts 1.12
import QtQuick.Window 2.12
import "Theme"
Window {
id: root
title: "Developer Tools"
color: Theme.toolbarBackgroundColor
ColumnLayout {
anchors.fill: parent
anchors.margins: 5
Skin.TextField {
id: searchField
Layout.fillWidth: true
placeholderText: "Search Term..."
onTextChanged: controlModel.setFilterFixedString(text)
}
// FIXME: Header items currently get squeezed when the table is empty
// (i.e. if a non-existing search term was entered).
HorizontalHeaderView {
id: horizontalHeader
Layout.fillWidth: true
syncView: tableView
delegate: Item {
id: headerDlgt
required property int column
required property string display
implicitHeight: columnName.contentHeight + 5
implicitWidth: columnName.contentWidth + 5
visible: this.column < tableView.columnWidths.length
BorderImage {
anchors.fill: parent
horizontalTileMode: BorderImage.Stretch
verticalTileMode: BorderImage.Stretch
source: Theme.imgPopupBackground
border {
top: 10
left: 20
right: 20
bottom: 10
}
}
Text {
id: columnName
text: headerDlgt.display
anchors.fill: parent
anchors.margins: 5
elide: Text.ElideRight
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
font.family: Theme.fontFamily
font.capitalization: Font.AllUppercase
font.bold: true
font.pixelSize: Theme.buttonFontPixelSize
color: Theme.buttonNormalColor
}
Text {
id: sortIndicator
text: controlModel.sortDescending ? "▲" : "▼"
visible: controlModel.sortColumn == headerDlgt.column
anchors.fill: parent
anchors.margins: 5
elide: Text.ElideRight
horizontalAlignment: Text.AlignRight
verticalAlignment: Text.AlignVCenter
font.family: Theme.fontFamily
font.capitalization: Font.AllUppercase
font.bold: true
font.pixelSize: Theme.buttonFontPixelSize
color: Theme.buttonNormalColor
}
TapHandler {
onTapped: controlModel.toggleSortColumn(headerDlgt.column)
}
}
}
TableView {
id: tableView
property var columnWidths: [0.3, 0.4, 0.15, 0.15]
Layout.fillHeight: true
Layout.fillWidth: true
columnSpacing: 1
rowSpacing: 1
clip: true
onWidthChanged: forceLayout()
boundsBehavior: Flickable.StopAtBounds
model: Mixxx.ControlSortFilterModel {
id: controlModel
function toggleSortColumn(column) {
const descending = (sortColumn == column) ? !sortDescending : false;
sortByColumn(column, descending);
}
Component.onCompleted: {
// First order by key, then by group.
sortByColumn(1, false);
sortByColumn(0, false);
}
}
delegate: DelegateChooser {
DelegateChoice {
column: 0
delegate: Rectangle {
id: groupDelegate
required property int column
required property string display
implicitWidth: (root.width - 10) * tableView.columnWidths[groupDelegate.column]
implicitHeight: groupName.contentHeight
color: root.color
Text {
id: groupName
anchors.fill: parent
text: groupDelegate.display
verticalAlignment: Text.AlignVCenter
elide: Text.ElideRight
color: Theme.deckTextColor
}
}
}
DelegateChoice {
column: 1
delegate: Rectangle {
id: keyDelegate
required property int column
required property string display
implicitWidth: (root.width - 10) * tableView.columnWidths[keyDelegate.column]
implicitHeight: keyName.contentHeight
color: root.color
Text {
id: keyName
anchors.fill: parent
text: keyDelegate.display
verticalAlignment: Text.AlignVCenter
elide: Text.ElideRight
color: Theme.deckTextColor
}
}
}
DelegateChoice {
column: 2
delegate: Rectangle {
id: valueDelegate
required property int row
required property int column
required property string display
implicitWidth: (root.width - 10) * tableView.columnWidths[valueDelegate.column]
implicitHeight: valueField.implicitHeight
color: root.color
Skin.TextField {
id: valueField
anchors.fill: parent
text: valueDelegate.display
inputMethodHints: Qt.ImhFormattedNumbersOnly
onEditingFinished: {
const idx = controlModel.index(valueDelegate.row, valueDelegate.column);
controlModel.setData(idx, parseFloat(text));
}
color: Theme.textColor
background: Rectangle {
anchors.fill: parent
color: Theme.embeddedBackgroundColor
radius: 5
}
validator: DoubleValidator {
}
}
}
}
DelegateChoice {
column: 3
delegate: Rectangle {
id: parameterDelegate
required property int row
required property int column
required property string display
implicitWidth: (root.width - 10) * tableView.columnWidths[parameterDelegate.column]
implicitHeight: valueField.implicitHeight
color: root.color
Skin.TextField {
id: valueField
anchors.fill: parent
text: parameterDelegate.display
inputMethodHints: Qt.ImhFormattedNumbersOnly
onEditingFinished: {
const idx = controlModel.index(parameterDelegate.row, parameterDelegate.column);
controlModel.setData(idx, parseFloat(text));
}
color: Theme.textColor
background: Rectangle {
anchors.fill: parent
color: Theme.embeddedBackgroundColor
radius: 5
}
validator: DoubleValidator {
}
}
}
}
}
}
}
}