-
Notifications
You must be signed in to change notification settings - Fork 101
/
publishing.gradle
115 lines (105 loc) · 3.84 KB
/
publishing.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
/*
* publishing.gradle
*
* This source file is part of the FoundationDB open source project
*
* Copyright 2015-2018 Apple Inc. and the FoundationDB project authors
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
apply plugin: 'com.jfrog.artifactory'
// Add various details to the pom file to allow for publishing
def addPublishingInfo(publication) {
publication.pom {
name = project.name
url = 'https://foundationdb.github.io/fdb-record-layer/'
licenses {
license {
name = 'The Apache License, Version 2.0'
url = 'https://www.apache.org/licenses/LICENSE-2.0'
}
}
developers {
developer {
name = 'FoundationDB'
}
}
scm {
url = 'https://github.com/FoundationDB/fdb-record-layer/'
connection = 'scm:git:git@github.com:FoundationDB/fdb-record-layer.git'
developerConnection = 'scm:git:git@github.com:FoundationDB/fdb-record-layer.git'
}
}
}
ext {
// Make the "addPublishingInfo" method visible from outside this plugin
addPublishingInfo = this.&addPublishingInfo
}
publishing {
publications {
library(MavenPublication) { publication ->
from components.java
artifact tasks.sourcesJar
artifact tasks.javadocJar
artifact tasks.testJar
addPublishingInfo(publication)
}
}
artifactoryPublish {
// As a safeguard, only actually publish to artifactory if -PpublishBuild=true is passed to gradle
// Note: skip is documented, but onlyIf seems to also be required to make this work for some reason
// See: https://gist.github.com/DALDEI/40925568cef57e16e8a7
def publishBuild = Boolean.parseBoolean(findProperty('publishBuild') ?: 'false')
skip = !publishBuild
onlyIf {
publishBuild
}
publications(publishing.publications.library)
}
}
if (System.getenv('ARTIFACTORY_USER') != null && System.getenv('ARTIFACTORY_KEY') != null) {
artifactory {
clientConfig.setIncludeEnvVars(true)
publish {
def artifactoryUrl = System.getenv('ARTIFACTORY_URL') ?: 'https://ossartifacts.jfrog.io/artifactory/'
contextUrl = artifactoryUrl
repository {
repoKey = System.getenv('ARTIFACTORY_REPO') ?: 'fdb-record-layer'
username = System.getenv('ARTIFACTORY_USER')
password = System.getenv('ARTIFACTORY_KEY')
}
defaults {
publications('mavenJava')
publishPom = publishBuild
publishArtifacts = publishBuild
publishBuildInfo = publishBuild
publishIvy = false
}
}
}
}
createDistribution.configure {
afterEvaluate {
dependsOn generatePomFileForLibraryPublication
from tasks.jar, tasks.sourcesJar, tasks.javadocJar, tasks.testJar, tasks.generatePomFileForLibraryPublication
rename { filename ->
GenerateMavenPom pomTask = tasks.generatePomFileForLibraryPublication
Jar jarTask = tasks.jar
if (filename == pomTask.destination.name) {
jarTask.archiveName.replace "jar", "pom"
} else {
filename
}
}
}
}